home *** CD-ROM | disk | FTP | other *** search
/ Software Vault: The Gold Collection / Software Vault - The Gold Collection (American Databankers) (1993).ISO / cdr24 / sdf21.zip / SDF.ASM < prev    next >
Assembly Source File  |  1993-05-20  |  25KB  |  1,023 lines
  1. Title 'SDF : Speedy Disk Formatter'
  2.  
  3. ; **************************************************************************
  4. ; * THIS PROGRAM IS PUBLIC DOMAIN. You Are Free To Use It And Redistribute *
  5. ; * It, As Long As No Profit Is Made Out Of It. Redistribution Costs May   *
  6. ; * Not Exceed $5. This Notice May Not Be Removed Or Altered In Any Way.   *
  7. ; * Use At Your Own Risk. Author Will Not Be Held Responsible For Any Dama-*
  8. ; * ge That Might Result Of Use Or Misuse. Enjoy.               *
  9. ; **************************************************************************
  10.  
  11. ; This program is inspired from QDR by Vernon D. Buerg, which unfortunately
  12. ; has a bug in handling 3.5" floppies.
  13.  
  14. ; Better late than never, I dedicate this program to Ward Christensen, who
  15. ; showed us the way in the good old CP/M days ...
  16.  
  17. ; Jacques Pierson, Belgrade (Belgium), November 1987.
  18. ; CIS 76446,1516
  19.  
  20. ; Modification history:
  21. ; September 1990:  fixed bug with DMA boundary errors, and added code to turn
  22. ;    off the drive motor quickly.
  23. ; October 1990:  fixed bug in above bug fix.
  24.  
  25. M24    =    0    ;set to one at work, for an Olivetti M24 (ATT 6300) 
  26.  
  27. bell    equ    7
  28. bs    equ    8
  29. lf    equ    0Ah
  30. cr    equ    0Dh
  31. escape    equ    1Bh
  32. ulc    equ    0C9h    ;graphic char - Upper Left Corner
  33. llc    equ    0C8h    ;Lower Left Corner
  34. urc    equ    0BBh    ;Upper Right Corner
  35. lrc    equ    0BCh    ;Lower Right Corner
  36. vb    equ    0BAh    ;Vertical Border
  37. hb    equ    0CDh    ;Horizontal Border
  38. ;
  39. hsr    equ    0EFh    ;Head Step Rate : 4 ms
  40. hst    equ    0    ;Head Settle Time : 0 ms
  41. ;
  42.  
  43.  
  44. SDF    segment
  45.     assume ds:SDF, ss:SDF ,cs:SDF ,es:SDF
  46.  
  47.     org    0100h        ;make this a COM file
  48.  
  49.  
  50. start:    jmp    GetCmdLine
  51.  
  52. ; First describe our Disk Base Parms. We will make INT 1Eh to point here
  53. ; while formatting. Put at head of program so people without an assembler
  54. ; can easily patch this area w/ DEBUG.
  55.  
  56. OurDBP    equ    $
  57.  
  58.     db    hsr        ;high nibble : heads step rate
  59.                 ;low nibble, head unload time
  60.     db    2        ;DMA mode
  61.     db    255        ;clock ticks before stopping drive motor
  62.     db    2        ;sector size - 2 => 512 bytes
  63.     db    9        ;How many sectors per track
  64.     db    42        ;Gap length between sectors for R/W ops
  65.     db    -1        ;data length - Not used
  66.     db    80        ;Gap length when formatting
  67.     db    0F6h        ;Formatting char. Dos likes F6's
  68.     db    hst         ;Head settle time in ms.
  69.     db    1        ;Motor speed up time in 1/4 sec.
  70.  
  71. Welcome    db    cr,lf,'Speedy Disk Formatter, V1.0, '
  72.     db    '(c) Jacques Pierson, Nov 1987$'
  73.  
  74. UsageMessage    equ    $
  75.     db    cr,lf,lf,'Usage:  SDF drv: [switches]',cr,lf
  76.     db    'drv: mandatory and is either A: or B:,',cr,lf
  77.     db    'No switch => format standard 360K diskette, no verify',cr,lf
  78.     db    '/Q        => format Quad density (3',0abh,'" 720K disk)',cr,lf
  79.     db    '/V        => force Verify after format',cr,lf
  80.     db    'Multiple switches may be combined, e.g. SDF b:/q/v.'
  81.     db    cr,lf,lf,'$'
  82.  
  83. DriveMissing    db    cr,lf,lf,'Invalid or missing Drive Spec !$'
  84.  
  85. WrongSwitch    db    cr,lf,lf,'Unknown /switch in command line !$'
  86.  
  87. InsertDisk    db    cr,lf,lf,'Insert diskette in drive '
  88. Drive        db    'A, and press ENTER when ready ...$'
  89.  
  90. Again        db    cr,lf,lf,'Format complete,'
  91. Clusters    db    '      K available to user.'
  92.         db    cr,lf,'Press ENTER to format another diskette, '
  93.         db    'or ESCape to quit...$'
  94.  
  95. Formatting    db    cr,lf,lf,'Formatting '
  96. DiskType    db    'DSDD, Without$'
  97. Verify        db    ' Verify.',cr,lf,'$'
  98.  
  99. Track        db    cr,'Track: '
  100. TrackNr        db    '   Side: '
  101. SideNr        db    '   $'
  102.  
  103. ShowRetry    db    bs,'R$'
  104.  
  105. WritingBoot    db    ' - writing BOOT$'
  106. WritingFAT    db    ', FATs$'
  107. WritingDIR    db    ', DIR.$'
  108.  
  109. ErrorTbl    db    1,'Invalid command                '
  110.         db    2,'Address mark not found.        '
  111.         db    4,'Requested sector not found.    '
  112.         db    8,'DMA overrun on operation.      '
  113.         db    10h,'Bad CRC on diskette read/write.'
  114.         db    20h,'Controller failure.            '
  115.         db    40h,'SEEK operation failed.         '
  116. EndOfErrTbl    equ    $
  117.  
  118. FatalErr    db    bell,cr,lf,lf,'Door Open, Write-protected disk,'
  119.         db    ' or Drive Fails to respond.'
  120.         db    cr,lf,'Please fix problem and hit Enter to continue,'
  121.         db    'or ESCape to abort...$'
  122.  
  123. BadClusters    db    cr,lf,lf,'Bad sectors :'
  124. BadClNr        db    '       Cluster(s) disabled.',cr,lf,lf,'$'
  125. ;
  126. ErrBadSec    db    bs,bs,', Sec: '
  127. ErrSec        db    ' , Error '
  128. ErrCode        db    '   hex : '
  129. ErrMsg        db    'Unknown error.                 ',cr,lf,'$'
  130. ;
  131. ;
  132. ; Flags, set according to switches
  133. ;
  134. OptionsFlag    db    0    ;default is No Verify, Normal Disk
  135. CtrlBreak    db    0    ;Ctrl-Break flag on entry
  136. ;
  137. ; Disk characteristics, other parms are found in BootSector
  138. ;
  139. DirSecs        dw    7    ;DIRectory size in sectors
  140. DskTrks        db    40    ;Cyls/disk
  141. CurTrk        db    -1    ;Current track
  142. CurDrv        db    0    ;Current drive, binary, BIOS way (A:=0,..)
  143. NeedSetup    db    1    ;nonzero if default parms are in effect
  144.  
  145.     even            ;Align for those w/8086 processors
  146.  
  147. RetryCount    dw    0    ;Count of retries
  148. MaxTries    dw    2    ;Maximum retries attempted
  149. BadSecCnt    dw    0    ;Count of Bad Sectors
  150. NextSec        dw    0    ;Temp storage for next sector #
  151. INT1Eoff    dw    0    ;INT 1Eh offset
  152. INT1Eseg    dw    0    ;INT 1Eh segment
  153. INT24off    dw    0    ;Critical error handler offset
  154. INT24seg    dw    0    ;Critical error segment
  155. ;
  156. HexTbl        db    '0123456789abcdef'
  157. ;
  158. ID_tbl        dw    Side0    ;addr of table of ID's for track 0, side 0
  159.  
  160. Side0        db    0,0,1,2
  161.         db    0,0,2,2
  162.         db    0,0,3,2
  163.         db    0,0,4,2
  164.         db    0,0,5,2
  165.         db    0,0,6,2
  166.         db    0,0,7,2
  167.         db    0,0,8,2
  168.         db    0,0,9,2        ;end of side 0
  169.  
  170.         db    0,1,1,2        ;side 1 now
  171.         db    0,1,2,2
  172.         db    0,1,3,2
  173.         db    0,1,4,2
  174.         db    0,1,5,2
  175.         db    0,1,6,2
  176.         db    0,1,7,2
  177.         db    0,1,8,2
  178.         db    0,1,9,2        ;end of track, side 1
  179.  
  180. SideLen        equ    36
  181. ;
  182. ;
  183. ; Anatomy of our Boot sector
  184. ;
  185. BootSector    equ    $
  186.  
  187.         jmp    BootMsg
  188.  
  189.         db    'SDF  v01'    ;OEM name, 8 chars
  190.         dw    512        ;Sector size
  191.         db    2        ;Cluster size in sectors
  192.         dw    1        ;Reserved sectors
  193.         db    2        ;Number of FATs
  194. DirSize        dw    112        ;Directory entries
  195. TotSecs        dw    720        ;Total sectors
  196. MediaDes    db    0FDh        ;Media descriptor
  197. FatSize        dw    2        ;FAT size in sectors
  198.         dw    9        ;Sectors per Track
  199.         dw    2        ;Number of heads
  200.         dw    0        ;Number of hidden sectors
  201.         db    0        ;filler
  202.         db    0        ;head
  203.         db    10        ;length    of BIOS    file
  204.         db    hsr        ;The DPB, remember ?
  205.         db    2
  206.         db    25h
  207.         db    2
  208.         db    9
  209.         db    42
  210.         db    -1
  211.         db    80
  212.         db    0F6h
  213.         db    hst
  214.         db    1
  215.  
  216. NoBootMsg    equ    $
  217.  
  218.     db    cr,lf,lf
  219.     db    ulc,50 DUP (hb),urc,cr,lf
  220.     db    vb,'   This diskette has been formatted by SDF and    ',vb,cr,lf
  221.     db    vb,'    contains no system to boot from. Either       ',vb,cr,lf
  222.     db    vb,'  remove it and hit a key to boot from hard disk  ',vb,cr,lf
  223.     db    vb,'  if any, or replace it with another disk with a  ',vb,cr,lf
  224.     db    vb,'   system to boot from and hit a key when ready.  ',vb,cr,lf
  225.     db    llc,50 DUP (hb),lrc,cr,lf,lf,0
  226.  
  227.  
  228. BootMsg:
  229.     cli                ;no interrupts
  230.     cld                ;forward direction
  231.     mov    AX,07C0h        ;Boot runtime address
  232.     mov    DS,AX            ;to DS
  233.     mov    ES,AX
  234.     mov    SS,AX
  235.     mov    SP,0            ;temp stack at top of segment 
  236.     mov    SI,(OFFSET NoBootMsg - OFFSET BootSector) ;Msg ptr
  237. BNextChar:
  238.     lodsb                ;Get byte fm msg
  239.     or    AL,AL            ;a null ?
  240.     je    ReBoot            ;yes, print msg done
  241.     mov    AH,0Eh            ;print char, no bells and whistles
  242.     int    10h            ;Bios output char INT
  243.     jmp    SHORT BNextchar        ;loop for all string
  244. ;
  245. ReBoot:    xor    AH,AH            ;wait for key hit
  246.     int    16h
  247.  
  248.     int    19h            ;and try booting again 
  249.  
  250.  
  251. BEndOfStuff    equ    $
  252.  
  253.     db    (510 - (BEndOfStuff - BootSector)) DUP (0)    ;filler
  254.  
  255.     db    55h,0AAh        ;DOS disk signature
  256. ;
  257. ; End of boot sector
  258. ;
  259. ; 
  260. ; First sector of File Allocation Table
  261. ;
  262. FatSec1    equ    $
  263.     db    0FDh            ;FAT - Media descriptor
  264.     db    0FFh
  265.     db    0FFh
  266.     db    509 DUP (0)        ;to get a full sector
  267.  
  268. FatSec2    db    512 DUP (0)        ;FAT, second sector
  269.     db    512 DUP (0)        ;FAT, third sector
  270. ;
  271. DirSec1    equ    $
  272. DskLbl    db    'SDF--------'        ;Dir entry for disk label, 11 char
  273.     db    28h            ;Attributes : Label + Archive
  274.     db    10 DUP (0)
  275. TimeLo    db    0
  276. TimeHi    db    0
  277. Date    dw    0
  278.     db    486 DUP (0)        ;full sector
  279. ;
  280. DirSec2    db    512 DUP (0)        ;2nd and other sectors
  281. ;
  282. ;
  283. ; Control-Break handler : DO NOT give user a chance to exit w/^C or Break
  284. ; without resetting the environement...
  285. ;
  286. ControlBreak: 
  287.  
  288.     iret                ;trap ^C and simply return
  289. ;
  290. ;
  291. ; Critical Error handler:  Same as above.  Note that, contrary to documentation
  292. ; (under DOS 2.1 at least), selecting 'a' under Abort/Retry/Fail does not put
  293. ; you into INT 23.
  294. ;
  295. CritError:
  296.     push    AX
  297.     push    DX
  298.     push    DS
  299.     push    CS
  300.     pop    DS
  301.     call    Restore
  302.     pop    DS
  303.     pop    DX
  304.     pop    AX
  305.     jmp    far cs:[INT24off]    ;go to the previous handler
  306. ;
  307. ; Let's go to it now
  308. ;
  309. GetCmdLine:
  310.  
  311.     mov    DX,offset Welcome    ;print welcome msg
  312.     call    PrintString
  313.     mov    SI,80H            ;Peek at input bfr char count
  314.     lodsb                ;get byte
  315.     cbw                ;make word
  316.     or    AX,AX            ;any option ?
  317.     jne    GCL1            ;yes
  318. Usage:    mov    DX,offset UsageMessage
  319.     call    PrintString        ;Print and fall thru ErrorExit
  320. ;
  321. ; Error Exit, w/ return code 1, Normal Exit, w/ return code 0
  322. ;
  323. ErrorExit:
  324.     mov    AL,1
  325.     jmp    SHORT    DoExit
  326. ;
  327. Abort:    call    Restore            ;Restore INT 1E, INT 35
  328. ;
  329. Exit:    mov    AL,0            ;normal exit, no error
  330. DoExit:    mov    AH,4Ch            ;Program Exit
  331.     int    21h
  332. ;
  333. ;
  334. ; Carry on parsing command line
  335. ;
  336. GCL1:    mov    CX,AX            ;got something in cmd line, count to CX
  337.     call    ParseSwitches        ;Parse cmd line "/" switches
  338.     mov    SI,81h            ;Get drive spec
  339. GCL2:    lodsb
  340.     cmp    AL,' '            ;skip spaces
  341.     loopz    GCL2
  342.     jcxz    Usage            ;Nuts, give Usage Msg
  343.     cmp    AL,cr
  344.     jz    Usage
  345.     and    AL,5fh            ;Make drive letter uppercase
  346.     mov    Drive,AL        ;Put drive letter in msg
  347.     sub    AL,'A'            ;make binary, BIOS way
  348.     mov    CurDrv,AL        ;Store in current drive
  349.     cmp    AL,1            ;Drive MUST be 0 or 1
  350.     jg    BadDrive
  351.     lodsb
  352.     cmp    AL,':'            ;Make sure this WAS a drive spec
  353.     jne    BadDrive        ;no, it was not
  354.     jmp    Setup            ;Yes, indeed
  355. BadDrive:
  356.     mov    DX,OFFSET DriveMissing
  357.     call    PrintString
  358.     jmp    Usage
  359. ;
  360. ;
  361. A$Ret:    ret
  362. ;
  363. ; Parse command line switches
  364. ;
  365. ParseSwitches:
  366.     mov    DI,81h            ;peek at cmd line
  367. PS1:    mov    AL,'/'
  368.     repne    scasb            ;search for "/", length in CX
  369.     jne    A$Ret            
  370.     jcxz    A$Ret            ;none, or no more
  371.     mov    BYTE PTR [DI-1],cr    ;Got a "/", put a CR for later use
  372.     cmp    BYTE PTR [DI-2],' '    ;Previous char was space ?
  373.     jne    PS2            ;no
  374.     mov    BYTE PTR [DI-2],cr    ;yes, force to CR
  375. PS2:    mov    SI,DI
  376.     lodsb                ;get switch
  377.     and    AL,5Fh            ;Force uppercase
  378. PS3:    cmp    AL,'V'            ;/Verify ?
  379.     jne    PS4            ;no
  380.     mov    OptionsFlag,1        ;yes, remember that
  381.     mov    WORD PTR DskLbl+6,'V+'    ;put in disk label
  382.     mov    BYTE PTR DiskType+10,'$' ;truncate "Without" msg
  383.     jmp    PS1            ;parse next
  384. PS4:    cmp    AL,'Q'            ;/Quad density ?
  385.     jne    PS5            ;no, unknown switch
  386.     mov    BYTE PTR DiskType+2,'Q'    ;Flag, and Description
  387.     mov    DskTrks,80        ;80 tracks
  388.     mov    FatSize,3        ;FAT is 3 sectors long
  389.     mov    TotSecs,1440        ;1440 sectors
  390.     mov    MediaDes,0F9h        ;to Boot Sector
  391.     mov    WORD PTR DskLbl+8,'Q+'    ;put in disk label
  392.     jmp    PS1            ;parse next switch
  393. PS5:    mov    DX,OFFSET WrongSwitch
  394.     call    PrintString
  395.     jmp    Usage    
  396.  
  397. ;
  398. ; Restore : Restore the world as it was on entry
  399. ;
  400. Restore:cmp    NeedSetup,0        ;see if we need to do this
  401.     jnz    Res1            ;if not
  402.     mov    NeedSetup,1
  403.  
  404.     lds    DX,DWORD PTR INT1Eoff    ;previous INT 1Eh vector
  405.     mov    AX,251Eh        ;restore it
  406.     int    21h
  407.     push    CS            ;restore DS
  408.     pop    DS
  409.  
  410.     mov    AH,0            ;Reset Disk System
  411.     int    13h
  412.  
  413.     mov    AX,3301h        ;set Ctrl-Break flag
  414.     mov    DL,CtrlBreak        ;restore as was on entry
  415.     int    21h
  416.  
  417. Res1:    ret
  418. ;
  419. ;
  420. ; Setup : Set up the world
  421. ;
  422. Setup:    mov    AH,AL            ;colon to AH
  423.     mov    AL,CurDrv
  424.     add    AL,'A'
  425.     mov    WORD PTR DskLbl+4,AX    ;put DriveSpec in disk label
  426.  
  427.     mov    AX,3300h        ;Get CtrlBreak flag
  428.     int    21h
  429.     mov    CtrlBreak,DL        ;save flag
  430.  
  431.     mov    DX,OFFSET ControlBreak    ;our handler
  432.     mov    AX,2523h        ;Set Interrupt Vector 23h
  433.     int    21h
  434.  
  435.     mov    AX,3524h        ;get Interrupt Vector 24h
  436.     int    21h
  437.     mov    INT24off,BX
  438.     mov    INT24seg,ES
  439.     mov    DX,OFFSET CritError    ;our handler
  440.     mov    AX,2524h        ;Set Interrupt Vector 24h
  441.     int    21h
  442.  
  443.     mov    AX,351Eh        ;get Interrupt Vector 1Eh
  444.     int    21h
  445.     mov    INT1Eoff,BX
  446.     mov    INT1Eseg,ES
  447.  
  448.     push    CS
  449.     pop    ES
  450.                     ;fall thru format loop
  451. ;
  452. Do_It:    mov    DX,OFFSET InsertDisk    ;say "Insert diskette in drive.."
  453.     call    PrintString
  454. ;
  455. GetChar:mov    AH,0            ;get char function
  456.     int    16h
  457.     cmp    AL,escape
  458.     jne    GC1
  459.     jmp    Abort
  460. GC1:    cmp    AL,cr
  461.     jne    GetChar            ;Escape or CR only !
  462.  
  463.     cmp    NeedSetup,0        ;see if we need to do this
  464.     je    GC2            ;if not
  465.     mov    NeedSetup,0
  466.  
  467.     mov    DX,OFFSET OurDBP    ;our DBP
  468.     mov    AX,251Eh        ;Set Interrupt Vector 1Eh
  469.     int    21h
  470.  
  471.     mov    AH,0            ;Reset Disk System
  472.     int    13h            ;our DBP is now in effect
  473.  
  474.     mov    AX,3301h        ;set flag
  475.     xor    DL,DL            ;set checking OFF
  476.     int    21h
  477.  
  478. GC2:    mov    DX,OFFSET Formatting    ;"Formatting..."
  479.     call    PrintString
  480.     mov    DX,OFFSET Verify
  481.     call    PrintString
  482.     mov    BadSecCnt,0        ;no bad sector so far
  483.     call    PrepareFat
  484. ;
  485. ; Format all disk now
  486. ;
  487.     call    DoFormat        ;Here we go
  488.     mov    AX,BadSecCnt        ;any bad sector ?
  489.     or    AX,AX
  490.     je    NoBadSec        ;no
  491.     mov    SI,OFFSET BadClNr    ;Pointer to decimal places
  492.     call    AX2dec            ;convert to decimal
  493.     mov    DX,OFFSET BadClusters    ;Bad Clusters msg
  494.     call    PrintString    
  495. ;
  496. ; Write Boot, FAT, DIR
  497. ;
  498. NoBadSec:call    WriteBFD        ;write Boot, Fat, Dir
  499. ;
  500. ; Show available space
  501. ;
  502.     mov    AH,0Dh            ;reset disk system
  503.     int    21h
  504.     mov    AH,36h            ;get free space
  505.     mov    DL,CurDrv        ;for our drive
  506.     inc    DL            ;DOS way
  507.     int    21h
  508.     mov    AX,BX            ;clusters to AX
  509.     mov    SI,OFFSET Clusters
  510.     call    AX2dec            ;convert and fall thru print
  511. ;
  512. ; Done - prompt for another disk to format
  513. ;
  514.     mov    DX,OFFSET Again        ;"Hit enter to format another..."
  515.     call    PrintString
  516.     call    MotorOff        ;Turn motor off
  517.     call    Whistle            ;Wake him up
  518.     jmp    GetChar            ;get char
  519.  
  520.  
  521. ;
  522. ; Prepare first FAT sector - This stuff required for multiple formatting
  523. ;
  524. PrepareFat:
  525.     sub    AX,AX            ;clear FAT to all zeros
  526.     mov    DX,FatSize        ;How many sectors ?
  527.     mov    DI,OFFSET FatSec1
  528. PF1:    mov    CX,512/2        ;sector size, in words
  529.     repz    stosw            ;for speed
  530.     dec    DX            ;next FAT
  531.     jnz    PF1
  532.     mov    AL,MediaDes        ;get Media Descriptor from Boot Sec
  533.     mov    BYTE PTR FatSec1,AL        ;move in place
  534.     mov    WORD PTR FatSec1+1,0FFFFh
  535.     ret
  536.  
  537. ;
  538. ; Here to REALLY format a disk
  539. ;
  540. DoFormat:
  541.     mov    CurTrk,-1        ;Initialize track nr
  542. NextTrk:                ;Prepare table for Track/sect. ID's
  543.     inc    CurTrk            ;Next track
  544.     mov    CH,CurTrk        ;to CH
  545.     cmp    CH,DskTrks        ;All done ?
  546.     jb    NT1            ;not yet
  547.     ret                ;yes, return
  548. NT1:    mov    DI,ID_tbl        ;Point to table
  549.     mov    AL,18            ;18 sectors per Cyl
  550. NT2:    mov    [DI],CH            ;move Track # in table
  551.     add    DI,4            ;point to next entry
  552.     dec    AL            ;all done ?
  553.     jnz    NT2            ;No, loop
  554.     mov    AH,1            ;Give user a chance to abort
  555.     int    16h            ;Keyboard hit ?
  556.     jz    NT3            ;no
  557.     cmp    AL,escape        ;yes, Escape to abort ?
  558.     jne    NT3
  559.     jmp    Abort
  560. ;
  561. NT3:    mov    AX,0509h        ;Format Track, 9 sectors/trk
  562.     mov    BX,ID_tbl        ;track id table address, side 0
  563.     mov    DL,CurDrv        ;current drive
  564.     mov    DH,0            ;Side 0
  565.     mov    CL,1            ;First sec is #1
  566.     call    PrintProgress        ;Print progress (Track#, Side #)
  567.     int    13h            ;Format track, side 0
  568.     jnc    NT3V            ;No Carry, no error
  569.     call    Retry            ;Carry set, Shall we retry ?
  570.     jnc    NT3            ;yes, if we come here w/Carry clear
  571.                     ;else, give up
  572. NT3V:    test    OptionsFlag,1        ;Should we verify ?
  573.     jz    NT4            ;No, next side
  574. ;
  575. NT3R:    mov    AX,0409h        ;Verify, 9 sectors per track
  576.     int    13h
  577.     jnc    NT4            ;No carry, no error
  578.     call    Retry            ;Carry set, retry ?
  579.     jnc    NT3R            ;Yes, if Carry clear, else give up
  580. NT4:    mov    DH,1            ;Side 1
  581.     mov    AX,0509h        ;Format Track, 9 sectors/trk
  582.     mov    BX,ID_tbl        ;track id table address, side 1
  583.     add    BX,SideLen
  584.     mov    DL,CurDrv        ;current drive
  585.     mov    CL,1            ;First sec is #1
  586.     call    PrintProgress        ;Print progress (Track#, Side #)
  587.     int    13h            ;Format track, side 1
  588.     jnc    NT4V            ;no error
  589.     call    Retry            ;Carry set, error
  590.     jnc    NT4            ;Retry if Carry clear, else give up
  591. NT4V:    test    OptionsFlag,1        ;Should we verify ?
  592.     jz    NextTrk            ;no, next track
  593. ;
  594. NT4R:    mov    AX,0409h        ;Verify, 9 sectors per track
  595.     int    13h
  596.     jc    NT5            ;error !
  597.     jmp    NextTrk            ;no error, next track
  598. NT5:    call    Retry            ;Carry set, retry ?
  599.     jnc    NT4R            ;yes
  600.     jmp    NextTrk            ;no, next track
  601. ;
  602. Retry:    cmp    AH,3            ;Door open/Write protected ?
  603.     je    R1            ;yes
  604.     cmp    AH,80h            ;Attachment failed to respond ?
  605.     jne    R2            ;no, other error
  606. R1:    mov    DX,OFFSET FatalErr    ;tell him he'd better close the door
  607.     call    PrintString        ;..or remove the write-protect tab
  608.     pop    AX            ;clean up stack, we won't return
  609.     pop    AX            ;two calls to clean up
  610.     jmp    GetChar            ;OK, we may restart now
  611. R2:    cmp    AH,9            ;DMA boundary error?
  612.     jne    R4            ;no, other error
  613.     push    CX            ;save registers
  614.     push    SI
  615.     mov    DI,ES            ;compute offset of next DMA page
  616.     neg    DI
  617.     mov    CL,4
  618.     shl    DI,CL
  619.     cmp    DI,EndCode
  620.     ja    R3            ;if it's not in the code segment
  621.     mov    DI,EndCode        ;don't clobber code
  622. R3:    mov    SI,ID_tbl        ;move the table pointer
  623.     mov    ID_tbl,DI
  624.     mov    CX,SideLen        ;move the table itself
  625.     rep    movsw
  626.     cmp    SI,DI
  627.     pop    SI            ;restore registers
  628.     pop    CX
  629.     je    R4            ;if this should already be fixed
  630.     clc
  631.     ret
  632. R4:    push    DX
  633.     mov    DX,OFFSET ShowRetry    ;Show 'R' to indicate a retry
  634.     call    PrintString
  635.     pop    DX
  636.     inc    RetryCount
  637.     mov    DI,MaxTries        ;limit exceeded ?
  638.     cmp    RetryCount,DI
  639.     ja    SecIsBad        ;Yes, this one is really bad
  640.     mov    AH,0            ;No, Reset Disk System
  641.     int    13h
  642.     clc                ;clear carry
  643.     ret                ;and return to try again
  644. ;
  645. ; If we come here, we really have to deal with a bad sector
  646. ;
  647. SecIsBad: call    ShowBadSec
  648.     inc    BadSecCnt        ;count it
  649.     call    MarkBad            ;Mark whole cluster
  650.     mov    RetryCount,0        ;Reset retry count
  651.     stc                ;Set Carry to indicate "give up"
  652.     ret                ;go process next side or track
  653. ;
  654. ;
  655. ; Mark a bad sector (cluster) in FAT
  656. ;
  657. MarkBad:push    AX
  658.     push    BX
  659.     push    CX
  660.     push    DX
  661.     push    DI
  662.     push    SI
  663.     push    DS            ;We have to fetch..
  664.     mov    AX,40h            ;.. the faulty sector
  665.     mov    DS,AX            ;.. in the BIOS area
  666.     mov    BX,47h
  667.     mov    CL,BYTE PTR [BX]    ;Get sector number
  668.     pop    DS
  669.     mov    AL,CH            ;Track # to AL; AH is already 0
  670.     xor    CH,CH
  671.     cmp    DH,0            ;Side 0 ?
  672.     je    MB1
  673.     add    CL,9            ;Side 1, add 9 sects for side 0
  674. MB1:    shl    AX,1            ;* 2 heads
  675.     mov    BX,9            ;* 9 sectors per track
  676.     mul    BX            ;compute absolute sector #
  677.     add    AX,CX
  678.     sub    AX,FatSize        ;minus 1st FAT size
  679.     sub    AX,FatSize        ;minus 2nd FAT size
  680.     sub    AX,DirSecs        ;minus Directory size
  681.     mov    BL,2            ;disk heads
  682.     div    BX
  683.     add    AX,1
  684.     mov    CX,3
  685.     mul    CX
  686.     shr    AX,1            ; / 2
  687.     mov    DI,AX
  688.     lea    SI,[DI+FatSec1]        ;pointer into FAT
  689.     mov    DI,SI
  690.     lodsw                ;get cluster entry
  691.     mov    DX,0FF70h        ;12 bits, left aligned
  692.     jb    MB2            ;if even
  693.     mov    DX,0FF7h        ;if odd
  694. MB2:    or    AX,DX            ;merge w/ word to mark bad
  695.     stosw                ;store back in FAT
  696.     pop    SI
  697.     pop    DI
  698.     pop    DX
  699.     pop    CX
  700.     pop    BX
  701.     pop    AX
  702.     ret
  703. ;
  704. ; Write Boot sector, then FATs, then DIR.
  705. ;
  706. WriteBFD:
  707.     mov    DX,OFFSET WritingBoot
  708.     call    PrintString
  709.     mov    AL,CurDrv
  710.     lea    BX,BootSector        ;boot sector
  711.     mov    CX,1            ;1 sector to write
  712.     mov    DX,0            ;absolute sector 0
  713.     call    AbsSecWrite
  714. ;
  715. ; Write FAT(s)
  716. ;
  717.     push    DX            ;Preserve Sector Nr
  718.     mov    DX,OFFSET WritingFAT    ;"FATs"
  719.     call    PrintString
  720.     pop    DX
  721.     mov    AL,CurDrv        ;current drive
  722.     lea    BX,FatSec1        ;point to FAT 1st sector
  723.     mov    CX,1            ;1 sector write
  724.     inc    DX            ;DX knows which
  725.     call    AbsSecWrite
  726.     mov    CX,FatSize        ;sectors/FAT
  727.     dec    CX            ;One written already
  728.     lea    BX,FatSec2        ;get FAT 2nd sector
  729.     mov    AL,CurDrv        ;current drive
  730.     inc    DX            ;next sector(s)
  731.     call    AbsSecWrite
  732.     add    DX,CX            ;count sectors written this time
  733. ;
  734. ; Write second FAT
  735. ;
  736.     mov    AL,CurDrv        ;current drive
  737.     mov    BX,OFFSET FatSec1    ;FAT
  738.     mov    CX,1            ;1 sector, DX knows which
  739.     call    AbsSecWrite
  740.     mov    CX,FatSize        ;How many remaining ?
  741.     dec    CX            ;One already written
  742.     mov    BX,OFFSET FatSec2    ;point to FAT 2nd sector
  743.     mov    AL,CurDrv        ;current drive
  744.     inc    DX            ;next FAT sector(s)
  745.     call    AbsSecWrite
  746.     add    DX,CX
  747.     mov    NextSec,DX        ;remember next sector to write
  748. ;
  749. ; Write Directory
  750. ;
  751.     mov    DX,OFFSET WritingDIR    ;"DIRectory"
  752.     call    PrintString
  753. ;
  754. ; Update Disk Label Date and Time
  755. ;
  756.     mov    AH,2Ch            ;Get Time
  757.     int    21h
  758.     mov    BX,CX            ;Minutes, Seconds
  759.     mov    AX,CX
  760.     mov    CL,3
  761.     shl    CH,CL            ;Shift to move hour in place
  762.     shr    BL,CL            ;Shift to keep high 3 bits of min
  763.     add    CH,BL            ;merge
  764.     mov    TimeHi,CH        ;move in place
  765.     and    AL,7            ;keep min. lower 3 bits
  766.     shl    AL,1            ;shift
  767.     mov    CL,5
  768.     shr    DX,CL            ;Shift seconds
  769.     add    DH,AL            ;merge
  770.     mov    TimeLo,DH        ;move in place
  771.     mov    AH,2Ah            ;Get Date
  772.     int    21h
  773.     sub    CX,1980            ;From 1980 on
  774.     shl    CL,1
  775.     mov    BX,DX
  776.     mov    AH,CL
  777.     mov    CL,3
  778.     shr    DH,CL
  779.     add    AH,DH
  780.     mov    CL,5
  781.     shl    BH,CL
  782.     add    BH,DL
  783.     mov    AL,BH
  784.     mov    Date,AX            ;Move date in place
  785.     mov    AL,CurDrv        ;current drive
  786.     mov    BX,OFFSET DirSec1    ;First sector of DIR
  787.     mov    DX,NextSec        ;current sector
  788.     mov    CX,1            ;1 sector to write
  789.     call    AbsSecWrite
  790.     mov    AL,CurDrv
  791.     mov    BX,OFFSET DirSec2
  792.     mov    CX,DirSecs        ;How many sectors
  793.     dec    CX            ;One already written
  794. WD1:    push    CX
  795.     mov    CX,1            ;1 sector write
  796.     inc    DX            ;next one
  797.     call    AbsSecWrite
  798.     pop    CX            ;how many remaining ?
  799.     loop    WD1
  800.     ret                ;Done, next disk please.
  801. ;
  802. ; Print progress : Track nn Side n - inline decimal conversion
  803. ;
  804. PrintProgress:
  805.     push    AX
  806.     push    DX
  807.     mov    AL,DH            ;Side #
  808.     add    AL,'0'            ;Brute force ascify
  809.     mov    SideNr,al        ;Put side # in msg
  810.     mov    AL,CH            ;get track #
  811.     aam                ;THE trick
  812.     xchg    AL,AH            ;swap
  813.     add    AX,'00'            ;Ascify
  814.     mov    WORD PTR TrackNr,AX    ;Put track # in msg
  815.     mov    DX,OFFSET Track        ;say "Track..., Side..."
  816.     call    PrintString
  817.     pop    DX
  818.     pop    AX
  819.     ret
  820. ;
  821. ; Here to show that we have a bad sector
  822. ;
  823. ShowBadSec:
  824.     push    AX
  825.     push    BX
  826.     push    CX
  827.     push    DX
  828.     push    DI
  829.     push    SI
  830.     mov    DX,AX            ;Save AX for further hex printing
  831.     sub    BX,BX
  832.     mov    BL,AH            ;remember error code
  833.     mov    DI,OFFSET ErrorTbl    ;Table for INT 13 error codes & msgs
  834.     mov    AL,AH            ;Error code to AL
  835.     MOV    CX,OFFSET EndOfErrTbl
  836.     sub    CX,DI            ;compute table length
  837.     repnz    scasb            ;search for error code
  838.     jnz    SBS1            ;Not found, "Unknown Error"
  839.     mov    SI,DI            ;Got it, Ptr to SI
  840.     mov    CX,31            ;err msg length
  841.     mov    DI,OFFSET ErrMsg    ;Point to destination
  842.     repz    movsb            ;Move Err Msg in place
  843. SBS1:    mov    AL,DH            ;Get AH : error code
  844.     call    AL2hex            ;Convert
  845.     mov    WORD PTR ErrCode,AX    ;move AH (hex) in msg
  846.     push    DS
  847.     mov    AX,40h            ;Point to BIOS data area
  848.     mov    DS,AX
  849.     mov    BX,47h            ;the right place in BIOS area
  850.     mov    AL,BYTE PTR [BX]    ;BIOS knows which sector causes problem
  851.     pop    DS
  852.     add    AL,'0'            ;ascify
  853.     mov    ErrSec,AL        ;move sec # in msg
  854.     mov    DX,OFFSET ErrBadSec    ;give error msg
  855.     call    PrintString
  856.     pop    SI
  857.     pop    DI
  858.     pop    DX
  859.     pop    CX
  860.     pop    BX
  861.     pop    AX
  862.     ret
  863. ;
  864. ;
  865. ; AL2hex : binary AL to 2 hex digits in AX conversion
  866. ;
  867. AL2hex:    push    BX
  868.     push    CX
  869.     push    DX
  870.     push    SI
  871.     mov    BL,AL            ;will use BX as offset to tbl
  872.     mov    CL,4            ;bits to shift
  873.     sub    BH,BH
  874.     shr    BL,CL
  875.     and    AL,0Fh            ;mask off bits
  876.     sub    AH,AH
  877.     mov    SI,OFFSET HexTbl    ;point to hex tbl
  878.     add    SI,BX
  879.     mov    DL,[BX+HexTbl]
  880.     mov    BX,AX
  881.     mov    DH,[BX+HexTbl]
  882.     mov    AX,DX
  883.     pop    SI
  884.     pop    DX
  885.     pop    CX
  886.     pop    BX
  887.     ret
  888. ;
  889. ;
  890. ; AX2dec : routine to convert AX to decimal string at DS:SI
  891. ;
  892. AX2dec:    push    AX
  893.     push    CX
  894.     push    SI
  895.     xor    CL,CL            ;clear 10000 counter
  896. s10000:    inc    CL
  897.     sub    AX,10000
  898.     jnc    s10000
  899.     add    AX,10000        ;one SUB too much
  900.     add    CL,'0'-1        ;adjust and ascify
  901.     mov    [SI],CL            ;store in string
  902.     inc    SI
  903.     xor    CL,CL            ;clear 1000 counter
  904. s1000:    inc    CL
  905.     sub    AX,1000
  906.     jnc    s1000
  907.     add    AX,1000            ;one SUB too much
  908.     add    CL,'0'-1        ;adjust and ascify
  909.     mov    [SI],CL            ;store in string
  910.     inc    SI
  911.     xor    CL,CL            ;clear 100 counter
  912. s100:    inc    CL
  913.     sub    AX,100
  914.     jnc    s100
  915.     add    AX,100            ;one SUB too much
  916.     add    CL,'0'-1        ;adjust and ascify
  917.     mov    [SI],CL            ;store in string
  918.     inc    SI
  919.     aam                ;Convert value <100
  920.     xchg    AL,AH            ;swap
  921.     add    AX,'00'            ;Ascify
  922.     mov    [SI],AX
  923.     pop    SI            ;restore string ptr
  924.     mov    CX,5            ; 5 bytes to search
  925. AX2D1:    cmp    BYTE PTR [SI],'0'    ;leading Zero ?
  926.     jne    AX2D2            ;no or no more
  927.     mov    BYTE PTR [SI],' '    ;yes, make leading space
  928.     inc    SI
  929.     loop    AX2D1            ;loop for all
  930. AX2D2:    pop    CX
  931.     pop    AX
  932.     ret
  933. ;
  934. ;
  935. ; PrintString : print string pointed by DX, terminated by '$'
  936. ;
  937. PrintString:
  938.  
  939.     push    ax
  940.     mov    ah,9
  941.     int    21h
  942.     pop    ax
  943.     ret
  944. ;
  945. ; Absolute sector Write
  946. ;
  947. AbsSecWrite:
  948.  
  949.     push    AX
  950.     push    BX
  951.     push    CX
  952.     push    DX
  953.     int    26h            ;absolute sector write
  954.     jnb    ASW1            ;no carry, no error
  955.     xchg    CX,DX
  956.     mov    DH,DL
  957.     call    ShowBadSec
  958. ASW1:    popf
  959.     pop    DX
  960.     pop    CX
  961.     pop    BX
  962.     pop    AX
  963.     ret
  964. ;
  965. ; MotorOff - Turn drive motor off
  966. ;
  967. motor_count    equ    440h
  968. ;
  969. MotorOff:
  970.     push    ds
  971.     xor    ax,ax
  972.     mov    ds,ax
  973.     mov    byte [motor_count],1    ;turn off drive motor next timer tick
  974.     pop    ds
  975.     ret
  976. ;
  977. ; Whistle - Wolf's whistle
  978. ;
  979. i8253    equ    40h        ;Timer chip base address
  980. i8255    equ    60h        ;PPI chip base address
  981. ;
  982. Whistle:
  983.     push    AX
  984.     mov    AL,0B6h        ;Counter 2, 2 bytes count, mode 3
  985.     out    (i8253+3),AL    ;Write Mode Word
  986.     mov    AX,1000        ;Divisor
  987.     push    AX
  988.     out    (i8253+2),AL    ;load lo byte
  989.     xchg    AH,AL
  990.     out    (i8253+2),AL    ;load hi byte
  991.     in    AL,(i8255+1)    ;8255, port B
  992.     or    AL,3        ;turn on bottom two bits, spkr on
  993.     out    (i8255+1),AL
  994.     pop    AX
  995. W1:    call    SwLoop        ;soft timing loop
  996.     dec    AX
  997.     out    (i8253+2),AL    ;load lo byte
  998.     xchg    AH,AL
  999.     out    (i8253+2),AL    ;load hi byte
  1000.     xchg    AH,AL
  1001.     jne    W1        ;loop
  1002.     in    AL,(i8255+1)    ;8255, port B
  1003.     and    AL,NOT 3    ;turn off bottom two bits, spkr off
  1004.     out    (i8255+1),AL
  1005.     pop    AX
  1006.     ret
  1007. ;
  1008. ; Soft loop for Whistle
  1009. ;
  1010. SwLoop:    push    CX
  1011.     mov    CX,100
  1012. SWL:    loop    SWL
  1013.     pop    CX
  1014.     ret
  1015. ;
  1016. ; End of code
  1017. ;
  1018. EndCode:
  1019. ;
  1020.     SDF    ends
  1021. ;
  1022. end    start
  1023.